Cách kết hợp hàm SORT với FILTER trong Google Sheets để lọc và sắp xếp dữ liệu

Kết hợp hàm SORT với FILTER trong Google Sheets là giải pháp tối ưu giúp lọc và sắp xếp dữ liệu tự động, chính xác và linh hoạt. Bằng cách sử dụng đồng thời hai hàm này, bạn có thể nhanh chóng phân loại thông tin theo điều kiện mong muốn. Đồng thời, bạn cũng dễ dàng sắp xếp kết quả theo thứ tự tăng dần hoặc giảm dần mà không cần thao tác thủ công. Bài viết này sẽ hướng dẫn chi tiết cách kết hợp hàm SORT với FILTER trong Google Sheets, kèm các ví dụ thực tế giúp việc quản lý dữ liệu trở nên chuyên nghiệp và hiệu quả. 

Hàm FILTER là gì và khi nào nên dùng? 

Hàm FILTER được thiết kế để trích xuất các hàng hoặc cột từ một phạm vi dữ liệu nguồn dựa trên một hoặc nhiều điều kiện logic mà bạn xác định. Hơn nữa, thay vì chỉ lọc tạm thời, hàm FILTER sẽ trả về một mảng kết quả mới tại vị trí ô bạn nhập công thức. Đồng thời cho phép bạn tiếp tục xử lý mảng này bằng các hàm khác. 

Chức năng của hàm FILTER

Hàm FILTER còn có chức năng sàng lọc một tập hợp dữ liệu lớn để chỉ giữ lại những hàng hoặc cột đáp ứng tất cả các tiêu chí đã đặt ra. Hàm FILTER sẽ thực hiện chính xác trong một công thức duy nhất và trả về một mảng kết quả gọn gàng.

Ngoài ra, bạn có thể dễ dàng thiết lập các điều kiện lọc dựa trên giá trị trong ô tham chiếu hoặc biến công thức, từ đó tạo ra công cụ lọc thông minh phục vụ cho việc tìm kiếm hay lập báo cáo tự động. Việc hiểu rõ cách sử dụng các điều kiện logic (như =, ≠, >, <) hoặc kết hợp nhiều điều kiện bằng phép nhân (*) cho AND và phép cộng (+) cho OR chính là chìa khóa để khai thác tối đa sức mạnh của hàm FILTER.

Sau khi đã có tập dữ liệu được lọc, bước tiếp theo bạn có thể thực hiện là sắp xếp kết quả theo thứ tự mong muốn — và đó chính là lúc hàm SORT phát huy tác dụng.

So với các bộ lọc thủ công, hàm FILTER có tính linh động hơn. Khi dữ liệu gốc thay đổi, kết quả của hàm FILTER sẽ tự động được tính toán lại ngay lập tức. 

Cú pháp cơ bản của hàm FILTER  

Cú pháp chuẩn của hàm FILTER trong Google Sheets như sau:

=FILTER(phạm_vi; điều_kiện_1; [điều_kiện_2; …])

Trong đó:

• phạm_vi (range): Là vùng dữ liệu bắt buộc mà bạn muốn lọc (ví dụ: A2:D100). Lưu ý, toàn bộ vùng bạn muốn hiển thị kết quả phải nằm trong phạm vi này.
• điều_kiện_1 (condition_1): Là một dải ô (ví dụ: C2:C100) hoặc một biểu thức logic (ví dụ: C2:C100=”Đã hoàn thành”). Dải ô điều kiện phải có cùng số hàng với phạm_vi.

Kết quả của điều kiện phải trả về giá trị TRUE hoặc FALSE — chỉ những hàng có giá trị TRUE mới được giữ lại trong kết quả lọc.

• [điều_kiện_2; …] hoặc [condition_2; …]: Mỗi điều kiện thêm vào sẽ được liên kết theo logic AND (VÀ) với điều kiện trước đó. Điều này có nghĩa là chỉ các hàng đáp ứng tất cả điều kiện đúng (TRUE) mới được hiển thị trong kết quả.

Ví dụ cơ bản về cách sử dụng hàm FILTER

Giả sử bạn có bảng dữ liệu bán hàng dưới đây:

*Yêu cầu 1: Lọc ra tất cả giao dịch có sản phẩm là “Laptop ASUS”.

Công thức:

=FILTER(A2:D8; C2:C8 = “Laptop ASUS”)

Trong đó:

• A2:D8 là vùng dữ liệu cần lọc.
• C2:C8 = “Laptop ASUS” là điều kiện để chỉ lấy các hàng có giá trị “Laptop ASUS” trong cột Tên sản phẩm.

Kết quả:

*Yêu cầu 2: Lọc theo điều kiện AND (VÀ):

Chỉ hiển thị các giao dịch có sản phẩm là “Laptop ASUS” và doanh thu ≥ 20.000.000.

Công thức:

=FILTER(A2:D8; C2:C8 = “Laptop ASUS”; D2:D8 >= 20000000)

Trong đó:

• Có 2 điều kiện được áp dụng đồng thời (AND):

C2:C8 = “Laptop ASUS” → lọc theo tên sản phẩm.

D2:D8 >= 20000000 → lọc theo doanh thu từ 20 triệu trở lên.

• Chỉ những hàng thỏa cả hai điều kiện TRUE mới được hiển thị.

Kết quả: 

*Yêu cầu 3 – Lọc theo điều kiện OR (HOẶC):

Hiển thị các giao dịch có Tên sản phẩm là “Laptop ASUS” hoặc “Macbook Pro”.

Công thức:

=FILTER(A2:D8; (C2:C8 = “Laptop ASUS”) + (C2:C8 = “Macbook Pro”))

Trong đó:

• Dấu “+” thể hiện logic OR (HOẶC) trong hàm FILTER.
• Nếu một trong hai điều kiện đúng (TRUE), hàng đó sẽ được giữ lại trong kết quả.

Kết quả: 

Hàm SORT là gì và khi nào nên dùng?

Sau khi đã sử dụng hàm FILTER để trích xuất một tập hợp dữ liệu con, sau đó là sắp xếp tập dữ liệu đó theo một thứ tự logic (tăng dần hoặc giảm dần) dựa trên giá trị của một hoặc nhiều cột. Lúc này, hàm SORT là một công cụ xử lý mảng cho phép bạn sắp xếp toàn bộ phạm vi dữ liệu dựa trên giá trị của các cột bên trong phạm vi đó. Quan trọng hơn là kết quả trả về của nó cũng là một mảng dữ liệu mới đã được sắp xếp.

Chức năng của hàm SORT

Chức năng chính của hàm SORT là tổ chức lại các hàng hoặc cột trong một phạm vi dữ liệu theo thứ tự xác định. Chẳng hạn như khi bạn có một danh sách học sinh, muốn sắp xếp theo điểm trung bình từ cao xuống thấp. Hay khi bạn có danh sách giao dịch, bạn muốn sắp xếp theo ngày gần nhất.

Tương tự như hàm FILTER, hàm SORT cũng có lợi thế là tính tự động. Khi dữ liệu nguồn thay đổi, kết quả được trả về bởi hàm SORT sẽ tự động được sắp xếp lại mà không cần bất kỳ thao tác thủ công nào. 

Hơn nữa, hàm SORT cho phép bạn sắp xếp theo nhiều cấp độ khác nhau. Ví dụ, sắp xếp theo “Tên chi nhánh” (tăng dần) trước, sau đó sắp xếp các giao dịch trong cùng một chi nhánh theo “Doanh thu” (giảm dần). 

Cú pháp cơ bản của hàm SORT 

Cú pháp chuẩn của hàm SORT trong Google Sheets như sau:

=SORT(phạm_vi; cột_sắp_xếp_1; tăng_dần_1; [cột_sắp_xếp_2; tăng_dần_2; …])

Trong đó:

• phạm_vi (range):

Đây là đối số bắt buộc, đại diện cho vùng dữ liệu cần sắp xếp (ví dụ: A2:D100).

Lưu ý, khi kết hợp với hàm FILTER, phạm_vi thường chính là kết quả mảng lọc do FILTER trả về, chứ không phải vùng dữ liệu gốc.

• cột_sắp_xếp_1 (sort_column_1):

Là chỉ mục cột (theo thứ tự từ trái sang phải, bắt đầu từ 1) mà bạn muốn dùng để sắp xếp.

Ví dụ: Nếu vùng dữ liệu A2:D100, thì A là cột 1, B là cột 2, C là cột 3, D là cột 4.

Bạn có thể chỉ định trực tiếp số thứ tự hoặc tham chiếu cột (như 3 hoặc C2:C100).

• tăng_dần_1 (is_ascending_1):

Là đối số bắt buộc, xác định hướng sắp xếp:

Nhập TRUE để sắp xếp tăng dần (A → Z, nhỏ → lớn, cũ → mới).

Nhập FALSE để sắp xếp giảm dần (Z → A, lớn → nhỏ, mới → cũ).

• [cột_sắp_xếp_2; tăng_dần_2; …]:

Là tùy chọn bổ sung nếu bạn muốn sắp xếp dữ liệu theo nhiều tiêu chí.

Sau khi hàm SORT sắp xếp theo cột đầu tiên, nó sẽ tiếp tục sắp xếp các giá trị trùng lặp dựa trên cột thứ hai, và cứ thế tiếp tục theo thứ tự ưu tiên bạn thiết lập.

Ví dụ cơ bản về cách sử dụng hàm SORT

Ví dụ, dưới đây là bảng dữ liệu:

*Yêu cầu 1: Sắp xếp theo Điểm trung bình (GPA) giảm dần

Bạn muốn sắp xếp toàn bộ danh sách sinh viên theo GPA từ cao xuống thấp.

Trong phạm vi A2:C8, cột GPA là cột thứ 3.

Công thức:

=SORT(A2:C8; 3; FALSE)

Trong đó:

• A2:C8: Là phạm vi dữ liệu cần sắp xếp.
• 3: Là chỉ mục cột thứ 3 (cột “Điểm trung bình”).
• FALSE: Là tham số quy định sắp xếp giảm dần (từ điểm cao nhất xuống thấp nhất).

Kết quả: 

*Yêu cầu 2: Sắp xếp theo nhiều cột 

Giả sử bạn muốn:

• Ưu tiên sắp xếp theo Giới tính (cột 2) tăng dần → Nam trước, Nữ sau.
• Trong từng nhóm giới tính, tiếp tục sắp xếp theo GPA giảm dần.

Công thức:

=SORT(A2:C8; 2; TRUE; 3; FALSE)

Trong đó:

• 2; TRUE: Sắp xếp theo cột Giới tính (chỉ mục 2) theo thứ tự tăng dần (Nam → Nữ).
• 3; FALSE: Sau đó, trong mỗi nhóm giới tính, sắp xếp theo cột GPA giảm dần (điểm cao → thấp).

Kết quả: 

Vì sao nên kết hợp hàm SORT với FILTER trong Google Sheets?

Việc kết hợp hàm SORT với FILTER trong Google Sheets không chỉ là gộp hai chức năng lại với nhau. Điều này sẽ tạo ra một quy trình xử lý dữ liệu tự động, liền mạch. Ngoài ra, sự kết hợp hàm SORT với FILTER trong Google Sheets còn mang lại những ưu điểm sau đây:

• Đảm bảo tính linh hoạt tuyệt đối

Nếu bạn sử dụng bộ lọc thủ công, bạn phải: 1) Áp dụng điều kiện lọc, 2) Sắp xếp kết quả. Khi dữ liệu gốc thay đổi, bạn phải lặp lại cả hai bước. 

Ngược lại, công thức SORT(FILTER(…)) chỉ cần nhập một lần và kết quả sẽ tự động cập nhật tại chỗ. Bất cứ khi nào dữ liệu gốc có thêm hàng mới, hay giá trị hiện tại thay đổi, kết quả cuối cùng (đã được lọc và sắp xếp) sẽ phản ánh sự thay đổi đó ngay lập tức.

• Giúp tách biệt dữ liệu gốc và dữ liệu báo cáo

Khi bạn sắp xếp hoặc lọc dữ liệu gốc bằng các tính năng sẵn có, tức là đang thay đổi cách hiển thị của toàn bộ bảng tính. Điều này có thể làm hỏng thứ tự hoặc mất dữ liệu gốc là rất cao. 

Khi kết hợp hàm SORT với FILTER trong Google Sheet, công thức này tạo ra một mảng kết quả ảo ở một vị trí hoàn toàn khác. Dữ liệu gốc vẫn an toàn, không bị thay đổi, trong khi báo cáo của bạn được trình bày hoàn hảo. 

Tóm lại, việc kết hợp hàm SORT với FILTER trong Google Sheet là chuyển từ làm việc thủ công sang tự động, từ tĩnh sang động. Nhưng để hiểu rõ hơn về cách kết hợp hai hàm này, phần tiếp theo sẽ đi sâu vào cú pháp và các ví dụ thực tế để bạn có thể bắt đầu áp dụng ngay.

Cú pháp và cách sử dụng kết hợp hàm SORT với FILTER trong Google Sheets

Nguyên tắc cơ bản khi hợp hàm SORT với FILTER trong Google Sheets kết rất đơn giản: 

• Hàm FILTER nằm bên trong hàm SORT.
• Kết quả mà FILTER trả về (một mảng dữ liệu đã lọc) sẽ trở thành đầu vào của hàm SORT để sắp xếp theo thứ tự mong muốn.

Cú pháp kết hợp hàm SORT với FILTER

Cú pháp chuẩn khi kết hợp hàm SORT với FILTER trong Google Sheets như sau:

=SORT(FILTER(dải_ô; điều_kiện_1; [điều_kiện_2; …]); cột_sắp_xếp; tăng_dần; [cột_sắp_xếp_2; tăng_dần_2; …])

Trong đó:

• FILTER(dải_ô; điều_kiện_1; [điều_kiện_2; …])

Đây là phần lọc dữ liệu gốc theo các điều kiện bạn đặt ra (ví dụ: sản phẩm, ngày, doanh thu…).

Kết quả trả về là một mảng dữ liệu tạm thời (gọi là mảng ảo – Virtual Array), gồm những hàng đáp ứng đủ điều kiện.

• SORT(mảng_kết_quả_tạm_thời; cột_sắp_xếp; tăng_dần; …)

Hàm SORT bao bọc bên ngoài, nhận kết quả lọc từ FILTER làm phạm_vi (range) để sắp xếp.

Nhờ vậy, dữ liệu vừa được lọc, vừa được sắp xếp tự động mà không cần hai bước riêng biệt.

Ví dụ minh hoạ cụ thể bằng bảng dữ liệu 

Dưới đây là bảng dữ liệu mẫu:

Ví dụ 1: Lọc dữ liệu theo điều kiện và Sắp xếp Tăng dần 

Yêu cầu: Lọc danh sách nhân viên thuộc phòng Kinh doanh, sau đó sắp xếp theo cột Doanh thu tăng dần.

Công thức:

=SORT(FILTER(A2:D9; B2:B9=”Kinh doanh”); 4; TRUE)

Trong đó:

• FILTER(A2:D9; B2:B9=”Kinh doanh”): lọc ra các dòng có phòng ban là Kinh doanh.
• SORT(…; 4; TRUE): sắp xếp kết quả lọc theo cột thứ 4 (Doanh thu) tăng dần (TRUE).

Kết quả:

Ví dụ 2: Lọc dữ liệu theo nhiều điều kiện và Sắp xếp Giảm dần 

Yêu cầu:  Lọc ra những nhân viên thuộc phòng Kế toán và tháng = 2, sau đó sắp xếp theo Doanh thu giảm dần.

Công thức:

=SORT(FILTER(A2:D9; B2:B9=”Kế toán”; C2:C9=2); 4; FALSE)

Trong đó:

• FILTER(A2:D9; B2:B9=”Kế toán”; C2:C9=2): lọc các dòng có phòng ban là Kế toán và tháng = 2.
• SORT(…; 4; FALSE): sắp xếp theo Doanh thu (cột thứ 4) giảm dần (FALSE).

Kết quả:

Ví dụ 3: Sắp xếp theo nhiều cột sau khi lọc

Yêu cầu: Lọc ra những nhân viên có Doanh thu > 9.000.000, sau đó sắp xếp theo Phòng ban (B) tăng dần, rồi sắp xếp tiếp theo Doanh thu (D) giảm dần.

Công thức:

=SORT(FILTER(A2:D9; D2:D9>9000000); 2; TRUE; 4; FALSE)

Trong đó:

• FILTER(A2:D9; D2:D9>9000000): lọc các nhân viên có doanh thu lớn hơn 9.000.000.

• SORT(…; 2; TRUE; 4; FALSE):

Bước 1: sắp xếp theo cột thứ 2 (Phòng ban) tăng dần.

Bước 2: trong mỗi phòng ban, sắp xếp tiếp theo cột thứ 4 (Doanh thu) giảm dần.

Kết quả:

Ví dụ nâng cao khi kết hợp hàm SORT với FILTER trong Google Sheets

Khi đã thành thạo cú pháp cơ bản của việc kết hợp hàm SORT với FILTER trong Google Sheet, lúc này bạn dễ dàng xử lý các yêu phức tạp hơn. Các ví dụ nâng cao này thường liên quan đến việc sử dụng logic lọc OR, sắp xếp theo nhiều cấp độ ưu tiên, hoặc lồng ghép thêm các hàm khác vào công thức, có thể tham khảo như sau.

Ví dụ, bạn có bảng dữ liệu như dưới đây sau: 

Lọc theo nhiều điều kiện rồi sắp xếp theo nhiều cột  

Yêu cầu: Lọc ra nhân viên thuộc phòng Kinh doanh hoặc Kế toán, có Doanh thu > 100,000,000, sau đó:

• Sắp xếp theo Phòng ban (B) tăng dần.
• Trong cùng Phòng ban, sắp xếp theo Doanh thu (D) giảm dần.

Công thức:

=SORT(  FILTER(A2:E9;   ((B2:B9=”Kinh doanh”) + (B2:B9=”Kế toán”)) *(D2:D9>100000000));  2; TRUE;  4;FALSE)

Trong đó:

• FILTER(A2:E9, …) : lọc dữ liệu từ vùng A2:E9.

• • (B2:B9=”Kinh doanh”) + (B2:B9=”Kế toán”): lọc nhân viên thuộc 2 phòng này (dấu + nghĩa là “hoặc”).
  • (D2:D9>100000000): chỉ  lấy các dòng có doanh thu > 100.000.000.

• SORT(…, 2, TRUE, 4, FALSE):

• • 2, TRUE: sắp xếp theo Phòng ban (B) tăng dần.
  • 4, FALSE: trong cùng phòng, sắp xếp theo Doanh thu (D) giảm dần.

Kết quả: 

Sắp xếp theo nhiều chỉ số 

Yêu cầu: Lọc ra nhân viên có Mức thưởng > 800,000, rồi sắp xếp theo 3 cấp độ:

• Theo Phòng ban (B) tăng dần
• Theo Tháng (C) tăng dần
• Theo Doanh thu (D) giảm dần

Công thức:

=SORT(FILTER(A2:E9; E2:E9>800000);2; TRUE; 3; TRUE; 4; FALSE)

Trong đó:

• • FILTER(A2:E9; E2:E9>800000): lọc ra nhân viên có thưởng trên 800.000.

• SORT(…; 2; TRUE; 3; TRUE; 4; FALSE):

• • Sắp theo Phòng ban (A–Z).
  • Nếu cùng Phòng ban → sắp theo Tháng tăng dần.
  • Nếu cùng Tháng → sắp theo Doanh thu giảm dần.

Kết quả:

Kết hợp với các hàm khác trong cùng công thức 

Yêu cầu: Lọc ra các nhân viên có Doanh thu lớn hơn trung bình toàn bộ (dùng hàm AVERAGE), rồi sắp xếp giảm dần theo Doanh thu, sau đó hiển thị thêm cột thưởng tương ứng.

Công thức:

=SORT( FILTER(A2:E9; D2:D9>AVERAGE(D2:D9));  4; FALSE)

Trong đó:

• AVERAGE(D2:D9): tính trung bình toàn bộ doanh thu.
• FILTER(A2:E9; D2:D9>AVERAGE(D2:D9)): chỉ lấy nhân viên có doanh thu cao hơn trung bình.
• SORT(…; 4; FALSE): sắp xếp theo Doanh thu (cột 4) giảm dần.

Kết quả:

Các lỗi thường gặp khi kết hợp hàm SORT với FILTER trong Google Sheets

Việc kết hợp hàm SORT với FILTER trong Google Sheets đôi khi cũng dễ xảy ra lỗi nếu bạn không nắm rõ nguyên tắc hoạt động của mảng. Khi đó, công thức sẽ trả về một thông báo lỗi. Nếu bạn hiểu rõ nguyên nhân của các lỗi phổ biến sẽ giúp nhanh chóng gỡ lỗi. 

Lỗi #VALUE!

Lỗi #VALUE! là một trong những lỗi phổ biến nhất khi sử dụng các hàm xử lý mảng như FILTER và SORT. Lỗi này thường xuất hiện khi Google Sheet không thể hiểu được giá trị được cung cấp, chủ yếu do sự không khớp về kích thước mảng hoặc tham chiếu sai kiểu dữ liệu.

Nguyên nhân và cách khắc phục lỗi #VALUE! khi kết hợp hàm cụ thể như sau:

• Thứ nhất là lỗi không khớp kích thước mảng

Trong hàm FILTER, tất cả các đối số điều kiện (điều_kiện_1, điều_kiện_2, …) phải có cùng số lượng hàng (hoặc cột) với đối số phạm_vi. 

Ví dụ lỗi, nếu phạm_vi là A2:D100 (99 hàng), nhưng điều_kiện_1 chỉ là C2:C99 (98 hàng), hàm FILTER sẽ trả về #VALUE!.

Cách khắc phục lỗi này là bạn luôn phải đảm bảo rằng các phạm vi điều kiện và phạm vi dữ liệu gốc đều có số lượng hàng (hoặc cột) giống hệt nhau, thường là bằng cách cố định phạm vi hàng (ví dụ: A2:D và C2:C).

• Thứ hai là lỗi tham chiếu kiểu dữ liệu không hợp lệ

Lỗi xảy ra khi một trong các đối số của hàm SORT không phải là kiểu dữ liệu mà nó mong muốn (ví dụ: dùng văn bản thay vì số cho cột_sắp_xếp).

Ví dụ lỗi, trong hàm SORT, đối số tăng_dần phải là TRUE hoặc FALSE. Nếu bạn nhập một số khác (ngoài 0 hoặc 1) hoặc một chuỗi văn bản không hợp lệ, lỗi #VALUE! có thể xảy ra.

Cách khắc phục lỗi là bạn luôn phải kiểm tra các đối số tăng_dần phải là TRUE hoặc FALSE.

Lỗi #REF!

Lỗi #REF! xảy ra khi một công thức tham chiếu đến một ô hoặc một phạm vi không hợp lệ. Khi kết hợp hàm SORT với FILTER trong Google Sheet, lỗi này thường liên quan đến không gian tràn mảng hoặc tham chiếu chỉ mục cột không tồn tại.

Nguyên nhân và cách khắc phục của lỗi #REF! khi kết hợp các hàm này là:

• Thứ nhất là lỗi không gian tràn màng

Hàm SORT(FILTER(…)) cần một vùng trống để hiển thị toàn bộ mảng kết quả của nó. Nếu bất kỳ ô nào trong vùng hiển thị đó đã chứa dữ liệu, công thức sẽ không thể mở rộng và trả về #REF!.

Ví dụ lỗi, bạn nhập công thức ở ô G2. Nếu ô G3, G4, hoặc bất kỳ ô nào bên dưới và bên phải G2 đã có dữ liệu, #REF! sẽ xuất hiện.

Khắc phục lỗi này rất đơn giản là xóa nội dung của tất cả các ô trong vùng mà mảng kết quả cần hiển thị.

• Thứ hai là chỉ mục cột hàm SORT vượt quá phạm vi

Lỗi này xảy ra khi bạn tham chiếu đến một chỉ mục cột nằm ngoài số lượng cột thực tế của mảng đã được lọc.

Ví dụ lỗi, hàm FILTER của bạn chỉ trả về một mảng có 5 cột (chỉ mục tối đa là 5), nhưng trong hàm SORT, bạn lại nhập 6 vào đối số cột_sắp_xếp.

Khắc phục lỗi này, bạn phải luôn đếm chính xác số cột trong phạm vi (dải_ô) của hàm FILTER và đảm bảo đối số cột_sắp_xếp của hàm SORT nằm trong khoảng từ 1 đến số cột đó.

• Thứ ba là tham chiếu phạm vi bị xóa

Nếu công thức của bạn tham chiếu đến một ô (A1) hoặc một phạm vi (A2:D50) trong bảng dữ liệu gốc, và sau đó bạn xóa hoàn toàn hàng hoặc cột chứa phạm vi đó, Google Sheet sẽ thay thế tham chiếu bằng #REF! trong công thức.

Lỗi #N/A

Lỗi #N/A trong bối cảnh của hàm FILTER có một ý nghĩa rất cụ thể và thường không phải là một lỗi thực sự mà là một thông báo rằng không có dữ liệu nào thỏa mãn điều kiện lọc.

Nguyên nhân và cách khắc phục lỗi #N/A khi kết hợp các hàm như sau:

• Thứ nhất là không có dữ liệu nào thỏa mãn điều kiện lọc

Đây là nguyên nhân duy nhất và phổ biến nhất gây ra lỗi #N/A trong hàm FILTER.

Ví dụ, bạn lọc danh sách giao dịch cho Nhà Cung Cấp “Nokia” trong khi không có giao dịch nào của Nokia. Hàm FILTER sẽ trả về #N/A vì nó không tìm thấy hàng nào đáp ứng điều kiện.

Khắc phục lỗi này là nếu bạn mong đợi một kết quả trống, lỗi #N/A chỉ là xác nhận rằng điều kiện của bạn đã hoạt động và không tìm thấy gì.

• Thứ hai là lỗi logic

Đôi khi lỗi #N/A xảy ra do bạn nhập sai chính tả trong điều kiện lọc (ví dụ: nhập “Markting” thay vì “Marketing”). Lúc này, lỗi #N/A cho bạn biết là không có dữ liệu nào khớp với điều kiện sai đó.

Khắc phục lỗi này là kiểm tra lại chính tả, phân biệt chữ hoa/thường (nếu cần), và đảm bảo rằng giá trị so sánh trong điều kiện lọc là chính xác.

Lỗi #ERROR!

Lỗi #ERROR! là lỗi chung chung nhất và thường là kết quả của lỗi cú pháp trong công thức hoặc việc tham chiếu chéo không hợp lệ trong môi trường xử lý mảng.

Nguyên nhân và cách khắc phục lỗi #ERROR! chi tiết khi kết hợp các hàm như sau:

• Thứ nhất là lỗi cú pháp

Thiếu Ngoặc Đơn – là nguyên nhân phổ biến nhất. Khi kết hợp hàm SORT với FILTER trong Google Sheet, bạn có hai hàm lồng vào nhau, nên dễ bị thiếu ngoặc đóng. (Ví dụ: SORT(FILTER(… thay vì SORT(FILTER(…))).

Thiếu Dấu Phẩy/Chấm Phẩy – sai sót khi sử dụng dấu phân cách giữa các đối số.

Cách khắc phục lỗi là luôn kiểm tra cấu trúc công thức một cách cẩn thận, sử dụng các gợi ý cú pháp của Google Sheet (các đối số sẽ được in đậm khi bạn nhập đúng cú pháp) và đếm số lượng ngoặc đơn mở và đóng.

• Thứ hai là lỗi ký tự không hợp lệ

Sử dụng các ký tự đặc biệt hoặc dấu nháy không đúng tiêu chuẩn trong chuỗi văn bản so sánh. Ví dụ, dùng dấu nháy đơn ‘…’ thay vì dấu nháy kép “…” cho chuỗi văn bản.

Lưu ý quan trọng khi kết hợp hàm SORT với FILTER trong Google Sheets

Để sử dụng hiệu quả và tránh các lỗi khi kết hợp hàm SORT với FILTER trong Google Sheet, bạn cần ghi nhớ một số quy tắc và mẹo nhỏ nhưng cực kỳ quan trọng sau đây.

• Thứ nhất là nguyên tắc “Chỉ mục Cột” trong SORT

Chỉ mục cột (cột_sắp_xếp) trong hàm SORT phải là chỉ mục tương đối, đếm từ cột đầu tiên của phạm vi mà hàm FILTER trả về. 

Ví dụ: Nếu FILTER trả về các cột C, D, E của bảng gốc. Cột C là chỉ mục 1, D là 2, E là 3. Nếu bạn muốn sắp xếp theo cột E, bạn phải dùng chỉ mục 3 chứ không phải chỉ mục tuyệt đối của E (thường là 5).

• Thứ hai là sử dụng phạm vi mở để đảm bảo tính động

Khi xác định dải_ô cho hàm FILTER và các phạm vi điều kiện, bạn nên sử dụng phạm vi mở ở cuối (ví dụ: A2:D thay vì A2:D1000).

Việc sử dụng A2:D đảm bảo rằng nếu bạn thêm hàng mới vào bảng gốc, công thức SORT(FILTER(…)) sẽ tự động bao gồm các hàng mới đó trong quá trình lọc và sắp xếp mà không cần phải chỉnh sửa công thức.

• Thứ ba là tối ưu hóa vị trí đặt công thức

Các hàm mảng như SORT(FILTER(…)) nên được đặt ở vị trí riêng biệt (thường là ở ô A1 hoặc A2 của một Sheet mới dành riêng cho Báo cáo). Việc này giúp tránh lỗi #REF! (vì không có dữ liệu nào khác chặn vùng tràn mảng) và tách biệt rõ ràng dữ liệu gốc (Sheet 1) với báo cáo đã xử lý (Sheet 2), tuân thủ nguyên tắc bảo tồn dữ liệu gốc.

Lời kết

Việc kết hợp hàm SORT với FILTER trong Google Sheets là giải pháp hoàn hảo để tạo ra các báo cáo động, tự động trích xuất và trình bày dữ liệu một cách linh hoạt, chính xác. Nếu còn bất kỳ thắc mắc nào về cách kết hợp hàm SORT với FILTER, hãy liên hệ GCS Việt Nam qua các kênh hỗ trợ để nhận được sự tư vấn chuyên sâu và giải pháp tối ưu cho mọi vấn đề dữ liệu của bạn.

• Fanpage: GCS – Google Cloud Solutions 

• Hotline: 024.9999.7777